Arbejde med arkfaner

Det kan være ganske nyttigt, at oprette arkfaner og flytte informationer mellem arkfanerne. I arbejdet med arkfaner har er der to nyttige objekter ActiveSheet og Worksheets.

Worksheets

Er en objektsamling af alle arkfaner med mange interessante anvendelser. Lad os se et par eksempler

Worksheets("Ark2").Activate

vil aktivere Ark2.

Dim ws As Worksheet
For Each ws In Worksheets
  MsgBox ws.Name
Next

vil løbe alle arkfaner igennem og vise deres navn i en messagebox.

Worksheets.Add(after:=Worksheets("Ark2"), Type:=xlWorksheet).Name = "Nyt arknavn"

Vil oprette en ny arkfane med navnet "Nyt arknavn" efter "Ark2". Bemærk den nye metode til at overføre informationer til Add metoden. Add metoden forventer 4 parametre: Add(Before, After, Count, Type). I stedet for at overføre alle 4 parametre i den rækkefølge de forventes kan man nøjes med at overføre de parametre man faktisk vil overføre og ved at bruge notationen med := kan man overføre dem i den rækkefølge man ønsker.

En anden nyttig konstruktion er

Worksheets.Add(after:=Worksheets(Worksheets.Count), Type:=xlWorksheet).Name = "Nyt arknavn"

der vil oprette en arkfane med navnet "Nyt arknavn" i efter de arkfaner der er i forvejen.

Der er naturligvis en række andre interessante metoder og egenskaber til Worksheets objektsamlingen - de kan alle ses hvis man skriver Worksheets. i VBA editoren. En sidst der skal nævnes her er delete metoden.

Application.DisplayAlerts = False
Worksheets("Ark3").Delete
Application.DisplayAlerts = True 

der vil slette Ark 3 uden varsel - uden Application.DisplayAlerts = False vil Excel komme ud med en advarsel inden arket slettes.

Activesheet

Activesheet har stort set de samme metoder og egenskaber som Worksheets. Activesheet peger bare kun på ét ark, nemlig det aktive. Dvs. man kan skrive Activesheet.Name, Activesheet.Delete etc.

Variable

Erfaringen viser, at det kan være en godt idé at bruge variable når man arbejder med arkfaner - det kunne se sådan her ud:

Dim wksAktuelle As Worksheet
Set wksAktuelle = Activesheet

Vi bruger Set her fordi Worksheet er et objekt.

Findes arkfanen?

Et par eksempler på kode, der kan afgøre om en arkfane findes:

Function FindesArkfanen(navn As String) As Boolean
  Dim wks As Worksheet
  On Error Resume Next
  Set wks = Sheets(navn)
  If wks Is Nothing Then 'Arkfanen findes ikke
    MsgBox "Arkfanen findes ikke", vbCritical,""
    Set wks = Nothing
    FindesArkfanen = False
    On Error GoTo 0
  Else 'Findes
    MsgBox "Arkfanen findes", vbInformation, ""
    Set wks = Nothing
    FindesArkfanen = True
    On Error GoTo 0
  End If
End Function

Og en lidt kortere udgave, der ikke bruger "On Error"

Public Function FindesArkfanen(navn As String) As Boolean
  FindesArkfanen = Not (IsError(Evaluate(navn & "!A1")))
End Function